[Iska]

galclerik, образец файла из нескольких строк выложите (нужно опознать кодировку).

([0-2] [0-4]-часы, [0-5] [0-9]-минуты, [0-5] [0-9]-секунды ) . »

И будет что-нибудь наподобие «24 часа 5 минут». И никогда не будет, скажем, ни 5, ни 15 часов .

[galclerik]

Вот прикладываю файл! Спасибо за быстрый ответ!

[Iska]

Ага. UTF-8, без BOM, Unix-like разделители. Длина файла какая бывает (в среднем)?

На WSH:

читать дальше »

Код:

Option Explicit

Dim strSourceFile

Dim lngDayOnSeconds
Dim objRegExp
Dim arrContent
Dim i


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0) '"E:\Песочница\0335\076"
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FileExists(strSourceFile) Then
			Randomize Timer
			
			lngDayOnSeconds = 24 * 60 * 60
			
			Set objRegExp = WScript.CreateObject("VBScript.RegExp")
			
			objRegExp.Pattern = "^(\d{2}\|\d{8}\|\d{8})(\d{6})(\|.*)$"
			
			With .OpenTextFile(strSourceFile)
				arrContent = Split(.ReadAll(), vbLf)
				.Close
			End With
			
			For i = LBound(arrContent) To UBound(arrContent)
				If objRegExp.Test(arrContent(i)) Then
					arrContent(i) = objRegExp.Replace(arrContent(i), "$1" & Replace(DateAdd("s", Rnd() * lngDayOnSeconds, 0), ":", "") & "$3")
				End If
			Next
			
			.CopyFile strSourceFile, .BuildPath(.GetParentFolderName(strSourceFile), .GetBaseName(strSourceFile) & ".bak"), True
			
			With .CreateTextFile(strSourceFile, True)
				.Write Join(arrContent, vbLf)
				.Close
			End With
			
			Set objRegExp = Nothing
		Else
			WScript.Echo "Source file [" & strSourceFile & "] not found."
			WScript.Quit 2
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

Можно просто перетаскивать потребный файл на скрипт.

[galclerik]

Количество строк в среднем достигает 35000.

Подскажи пожалуйста как пользоваться. (установлен windows7/32bit)Путь к папке я поменял, но вот при запуске и перетаскивании пишет "сценарий не указан"

И напиши в личку вебмоней или яндекс, перечислю на пиво, ну или на воду)

[Iska]

Путь к папке я поменял, »

Где? Там единственный путь, использовавшийся при отладке, и тот закомментирован.

Скопируйте приведённый код и сохраните его в файл с расширением «.vbs». Затем просто перетащите потребный файл на полученный скрипт.

И напиши в личку вебмоней или яндекс, перечислю на пиво, ну или на воду) »

Поскольку я денег принципиально не беру, а администрация, судя по всему, в подобных случаях отклоняет мои переадресации, привожу Вам адрес: Как помочь? | Фонд "Подари жизнь".

[galclerik]

Спасибо большое! Всё получилось! Только вот как можно доработать скрипт чтобы он также работал если у текста побольше размером строка(концовка после тексттексттекст всегда разная).
Например: 02|56873727|20131207011347|тексттексттекст|1|GFDRW|2|||99597970148|||||P||||||70090280174|32379|EV|| 0000000000|G|||||||||||||||||CDINhh02430||||||INhjtr1|||||+@@+

[Iska]

(концовка после тексттексттекст всегда разная). »

Я ведь не случайно просил «образец». В начале строк длины частей внутри разделителей хоть стабильны-то?

Я не вижу проблем на предложенной Вами строке: у меня отрабатывает корректно. А у Вас?

[galclerik]

Начало стабильно всегда. Отрабатывает почему-то так:

02|56873727|2013120574408|тексттексттекст
02|56873727|20131205121609|тексттексттекст
02|56873727|2013120535255|тексттексттекст
02|56873727|20131205235414|тексттексттекст
02|56873727|20131205194530|тексттексттекст
02|56873727|2013120565602|тексттексттекст

прикрепил фалы обработки.

[Iska]

galclerik, интересно было бы посмотреть на региональные стандарты. Исполните следующий код:

читать дальше »

Код:

Option Explicit

Dim i


With WScript.CreateObject("Scripting.FileSystemObject")
	With .CreateTextFile(.BuildPath(.GetParentFolderName(WScript.ScriptFullName), "list.txt"), True)
		For i = 0 To 24 * 60 * 60 - 1
			.WriteLine DateAdd("s", i, 0)
		Next
	End With
End With

WScript.Quit 0

и выложите в архиве содержимое полученного в результате исполнения файла «list.txt».