[Iska]

Правьте по своему разумению:

читать дальше »

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sRootFolder=E:\Песочница\0331

if exist "%sRootFolder%\." (
	for %%i in ("B" "C" "D" "E") do (
		if exist "%sRootFolder%\%%~i\." (
			echo Folder [%%~i] exists.
			
			for %%j in ("settings.dff" "develop.ini") do (
				if exist "%sRootFolder%\%%~i\%%~j" (
					echo 	File [%%~j] found in folder [%%~i].
				) else (
					echo 	File [%%~j] not found in folder [%%~i].
				)
			)
		) else (
			echo Folder [%%~i] not found.
		)
	)
) else (
	echo Can't find root folder [%sRootFolder%].
)

endlocal
exit /b 0

echo В ПАПКЕ "C" ВСЁ НА МЕСТЕ. »

Вместо этого я бы просто не выводил имена файлов и папок, которые «на месте». Это проще.

[feAre]

Кстати да, так лучше.
Лучше просто писать echo при нахождении ошибки какой-то.

[feAre]

Спасибо большое.
Решено.

Ой, тфу, забыл дополнить, извините.

Как переделать чтобы "settings.dff" , "develop.ini" искалось только в папке "B"
а ещё "1.txt" , "2.txt" искалось только в папке C

[Iska]

feAre, огласите весь список файлов.

[feAre]

Папка B
Файлы: "settings.dff" , "develop.ini"

Папка C:
Файлы: "1.txt" , "2.txt"

Папка D:
Файлы: "2.png", "2.png"

Папка E:
Файлы: "5.mp3" , "6.mp3"

И в корневой папке (%sFolder%)
"crashchecker.exe" , "ccsa.ini"

[Iska]

feAre, тогда только последовательно:

читать дальше »

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sFolder=E:\Песочница\0331

call :CheckFolderAndFiles "%sFolder%"   "crashchecker.exe" "ccsa.ini"
call :CheckFolderAndFiles "%sFolder%\B" "settings.dff"     "develop.ini" 
call :CheckFolderAndFiles "%sFolder%\C" "1.txt"            "2.txt"
call :CheckFolderAndFiles "%sFolder%\D" "2.png"            "2.png"
call :CheckFolderAndFiles "%sFolder%\E" "5.mp3"            "6.mp3"

endlocal
exit /b 0

:CheckFolderAndFiles
	setlocal enableextensions enabledelayedexpansion
	
	set sFolder=%~1
	if not exist "%sFolder%\." echo Folder [%sFolder%] not found.& goto :eof
:Repeat
	set sFile=%~2
	
	if not defined sFile goto :eof
	if not exist "%sFolder%\%sFile%" echo File [%sFile%] not found in folder [%sFolder%].
	
	shift /2
	goto :Repeat
	
	endlocal
	exit /b 0

Папка D: Файлы: "2.png", "2.png" »

Это как понимать?

[feAre]

опечатка.
хотел на три нажать, нажал на два.

Спасибо большое.

[feAre]

Каким-то образом появилась проблема.

Код:

call :CheckFolderAndFiles "%sFolderName%\models\txd\" "intro1.txd" "intro2.txd"

ищет только %sFolderName%, а не директорию в целом.

[Iska]

ищет только %sFolderName%, а не директорию в целом. »

Вопрос не понятен. Поясните.