[kiripanda]

проще всего – вставлять таб

[Iska]

с помощью батника …»

И где код?

[NibelungXXX]

проще всего – вставлять таб »

не поможет, обьем изменяется каждый раз и меняет расположение на чуть чуть, он то больше, то меньше))

И где код? »

я думал просто пример приведете а я сам вставлю) а так вот)

Код:

@echo off
for %%i in ("%cd%") do set "name=%%~nxi"
for %%i in (*.rar *.zip) do set /a count+=1
(echo имя %name%&echo количество %count%)>"%name%.txt"
>>"%name%.txt" echo 	^<№^>	^<Имя файла^>		^<Обьем^>		марка
set "count="
for %%i in (*.rar *.zip) do (
set /a count+=1
set /a size=%%~zi/1024
>>"%name%.txt" call echo %%count%%		%%i		%%size%% KB		GP
)

[Iska]

Пробуйте:

читать дальше »

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for %%i in ("%cd%") do set "name=%%~nxi"
for %%i in (*.rar *.zip) do set /a count += 1

>"%name%.txt" (
	echo Имя:        %name%
	echo Количество: %count%
	echo.
	
	call :EchoL "№"         10
	call :EchoS
	call :EchoL "Имя файла" 30
	call :EchoS
	call :EchoL "Обьем"     20
	call :EchoS
	call :EchoL "марка"     10
	echo.
	
	call :EchoC "-"         10
	call :EchoS
	call :EchoC "-"         30
	call :EchoS
	call :EchoC "-"         20
	call :EchoS
	call :EchoC "-"         10
	echo.
)

set "count="

for %%i in (*.rar *.zip) do (
	set /a count += 1
	set /a size = %%~zi / 2^10
	
	>>"%name%.txt" (
		call :EchoR "!count!"   10
		call :EchoS
		call :EchoL "%%~i"      30
		call :EchoS
		call :EchoR "!size! KB" 20
		call :EchoS
		call :EchoL "GP"        10
		echo.
	)
)

endlocal
exit /b 0
rem ==========================================================================

rem ==========================================================================
:PadLeft
	setlocal enableextensions enabledelayedexpansion
	
	set sOut=%~0
	set sVar=%~1
	set iCount=%~2
	
	for /l %%i in (1, 1, %iCount%) do set sSpace= !sSpace!
	set sTempVar=%sVar%%sSpace%
	set sTempVar=!sTempVar:~0,%iCount%!
	
	endlocal & set %sOut:~1%=%sTempVar%
	exit /b
rem ==========================================================================
	
rem ==========================================================================
:PadRight
	setlocal enableextensions enabledelayedexpansion
	
	set sOut=%~0
	set sVar=%~1
	set iCount=%~2
	
	for /l %%i in (1, 1, %iCount%) do set sSpace= !sSpace!
	set sTempVar=%sSpace%%sVar%
	set sTempVar=!sTempVar:~-%iCount%!
	
	endlocal & set %sOut:~1%=%sTempVar%
	exit /b
rem ==========================================================================

rem ==========================================================================
:EchoL
	call :PadLeft "%~1" "%~2"
	<nul set /p sTempVar=%PadLeft%
	exit /b
rem ==========================================================================

rem ==========================================================================
:EchoR
	call :PadRight "%~1" "%~2"
	<nul set /p sTempVar=%PadRight%
	exit /b
rem ==========================================================================

rem ==========================================================================
:EchoS
	<nul set /p sTempVar= 
	exit /b
rem ==========================================================================

rem ==========================================================================
:EchoC
	setlocal enableextensions enabledelayedexpansion
	
	set sChar=%~1
	set iCount=%~2
	
	for /l %%i in (1, 1, %iCount%) do set sString=!sString!%sChar%
	<nul set /p sTempVar=%sString%
	
	endlocal
	exit /b
rem ==========================================================================

Возможный результат:

Код: Имя: 0287 Количество: 3 № Имя файла Обьем марка ---------- ------------------------------ -------------------- ---------- 1 netscan.zip 9256 KB GP 2 scdwriter.zip 1940 KB GP 3 smartudm.zip 177 KB GP

[NibelungXXX]

Iska, а в чем причина, вставляя в код на сайт, все красиво, а в блокноте выглядит не ровно и даже когда код редактируешь тут все криво)) как избежать?

Код:

Имя:        k
Количество: 6

№          Имя файла                      Обьем                марка     
---------- ------------------------------ -------------------- ----------
         1 L3 0306.rar                                43315 KB GP        
         2 L1 0306.rar                                   13 KB GP        
         3 L2 0306.zip                                43315 KB GP        
         4 L1 0306.zip                               129957 KB GP        
         5 L1 0310.zip                                86636 KB GP        
         6 L1 2256.zip                               173292 KB GP

[Sphinx114]

NibelungXXX, юзать моноширинные шрифты, например Courier New, лично я использую DejaVu Sans Mono

[Iska]

Лучше всего смотрится Consolas, 14-16 кеглем — в зависимости от dpi монитора. Причём, желательно полноценный шрифт, содержащий дополнительные глифы.

[NibelungXXX]

Iska, Sphinx114 спасибо, все получилось что запланировал

[NibelungXXX]

Перенес на 7ку данный скрипт и не работает выравнивание, подскажите как к 7ке его адаптировать?, все выводит а конечный результат:

Код:

Имя:        k
Количество: 6

№          Имя файла                      Обьем                марка     

1.L3 0306.rar           43315 KB GP        
2.L1 0306.rar           13 KBGP        
3.L2 0306.zip           43315 KBGP        
4.L1 0306.zip           129957 KBGP        
5.L1 0310.zip           86636 KBGP        
6.L1 2256.zip           173292 KBGP
Режим вывода команд на экран (ECHO) отключен.

Режим вывода команд на экран (ECHO) отключен. - тоже не нужно чтоб писало