[Iska]

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

call :GetDateTime
set sFileName=%DateTime:~0,4%_%DateTime:~4,2%_%DateTime:~6,2%#%DateTime:~8,2%_%DateTime:~10,2%.zip

set sFolderList=%~1

if defined sFolderList (
	if exist "%sFolderList%" (
		"%ProgramFiles%\7-Zip\7z.exe" a -ir@%sFolderList% "%sFileName%"
	) else (
		echo Can't find folder list file [%sFolderList%].
	)
) else (
	echo Usage: %~nx0 ^<Folder list^>
)

endlocal
exit /b 0

rem ==========================================================================
rem Функция GetDateTime()
rem
rem Серый форум / CMD/BAT: получение формата дата-время для имени файла
rem (http://forum.script-coding.com/viewtopic.php?id=5066)
rem ==========================================================================
:GetDateTime
	setlocal enableextensions enabledelayedexpansion
	
	set sProcName=%~0
	for /f "delims=." %%i in ('wmic.exe OS get LocalDateTime ^| find "."') do set sDateTime=%%i
	
	endlocal & set %sProcName:~4%=%sDateTime:~0,14%
	exit /b 0
rem ==========================================================================

О формате файла-списка, содержащего имена файлов и папок, прочтите в документации:

Код:

hh.exe "mk:@MSITStore:%ProgramFiles%\7-Zip\7-zip.chm::/cmdline/syntax.htm#ListFile"

Обратите внимание на кодировку файла-списка.

[r-studio]

Iska, Снимаю шляпу!! Спасибо за Вашу помощь. А что такое Rem Серый форум
и код файла списка это уже отдельный батник?

[Iska]

А что такое Rem Серый форум »

Серый форум

читать дальше »

конкретно приведена ссылка на тему с использованным кодом: CMD/BAT: получение формата дата-время для имени файла (Страница 1) — CMD/BAT — Серый форум, идея которого, в свою очередь, была почерпнута из поста тутошнего участника amel27. Вот такой круговорот воды идей в природе.

и код файла списка это уже отдельный батник? »

Отдельный текстовый файл:

нaбop пaпoк (oни пеpечисл. в текстoвoм фaйле) »

[vanoman]

Кстати давно себе тоже искал подобную тему!

[r-studio]

Iska,
т.е. эту часть кода

читать дальше »

rem ==========================================================================
rem Функция GetDateTime()
rem
rem Серый форум / CMD/BAT: получение формата дата-время для имени файла
rem (http://forum.script-coding.com/viewtopic.php?id=5066)
rem ==========================================================================
:GetDateTime
setlocal enableextensions enabledelayedexpansion

set sProcName=%~0
for /f "delims=." %%i in ('wmic.exe OS get LocalDateTime ^| find "."') do set sDateTime=%%i

endlocal & set %sProcName:~4%=%sDateTime:~0,14%
exit /b 0
rem ==========================================================================

можно опустить?

[Iska]

Опустить эту часть кода, конечно, можно. Только вот оставшаяся часть кода пакетного файла без этого работать не будет .

[r-studio]

вроде делал все так, но ошибка пути нашлась?

[Iska]

r-studio, на Вашем скриншоте невозможно разобрать буквы.

[r-studio]

Iska,
давайте прикреплю её.))