[okshef]

1) F5 - Выделить группу ячеек - Формулы - OK

2) Вкладка "Формулы" - Показать формулы (или используйте сочетание клавиш Ctrl + `)

[a_axe]

okshef, спасибо. Пользовался вторым способом, а вот про первый забыл - в моем случае он более удобный, т.к. позволяет выделить цветом нужные ячейки (от "ctrl+`" уже реально в глазах рябит, тяжело вглядываться, большой шанс пропустить ячейку).
И все же это не совсем то, что я хотел - т.к. цель расчетов другая, и отвлекаться на контроль этих ячеек сильно не хочется, поэтому хотелось бы реализовать полностью автоматическое условное выделение форматирование.

Нашел способ создавать макрофункцию "=получить.ячейку(48;Лист1!A1)" и присваивать ей имя в диспетчере имен Источник, это именно то, что я хочу - но работает только на одном листе (в данном случае - "Лист1"), если листов будет 20 - нужно присваивать 20 имен Соответственно, когда таких файлов несколько, опять же не смешно.
К сожалению в Макрофункциях я мало что понимаю, да и в именах не особо...
Как вариант буду пользоваться F5, наверное самый приемлемый способ

[Iska]

a_axe, ну, добавьте в модуль рабочего листа что-нибудь наподобие:

Код:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim objCell As Range
    
    For Each objCell In Target
        If objCell.HasFormula Then
            objCell.Interior.ColorIndex = 27
        Else
            objCell.Interior.ColorIndex = 24
        End If
    Next
End Sub

Если именно:

Один из столбцов »

а прочее не трогать, то:

Код:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim objCell As Range
    Dim objTargetRange As Range
    Dim objIntersectRange As Range
    
    Set objTargetRange = ThisWorkbook.Worksheets.Item("Лист1").Range("D2:D20")
    Set objIntersectRange = Application.Intersect(objTargetRange, Target)
    
    If Not objIntersectRange Is Nothing Then
        For Each objCell In objIntersectRange
            If objCell.HasFormula Then
                objCell.Interior.ColorIndex = 27
            Else
                objCell.Interior.ColorIndex = 24
            End If
        Next
    End If
End Sub

[Iska]

Хех, только хотел пожаловаться, что нет «ThisWorksheet» (по аналогии с «ThisWorkbook»), но вовремя вспомнил . Для ссылки на рабочий лист, который содержит вышеприведённый код, вместо:

Код:

Set objTargetRange = ThisWorkbook.Worksheets.Item("Лист1").Range("D2:D20")

можно попробовать:

Код:

Set objTargetRange = Me.Range("D2:D20")

[a_axe]

Iska, спасибо за развернутый и проработанный ответ. Попробовал ваш способ, и вся моя решимость не использовать VBA растворилась в воздухе)))
Строка "Set objTargetRange = Me.Range("D2:D20")" работает.
Расчет достаточно сложный, но структурированный (однотипные расчетные листы и несколько сводных расчетов - максимум 3 на файл), поэтому вашу программу легко удалось адаптировать к конкретной таблице.

Практически ничего менять не пришлось, адаптировал следующее:
1. Событием сделал изменение в документе

Код:

Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

2. Проверяемым диапазоном сделал открытый лист (с рабочих листов нет ссылок на другие листы)

Код:

Set objTargetRange = ActiveSheet.Range("e2:e20")

3. Добавил проверку, что открытый лист не является сводным

Код:

If Not left(ActiveSheet.Name,7) = "Сводная" Then

okshef, Iska еще раз спасибо за помощь. Всегда приятно, когда кто-то другой делает за тебя твою работу , особенно когда времени катастрофически нет.

[Iska]

Событием сделал изменение в документе »

Будьте готовы к тому, что на поиск/замену не отработает (помнится, читал, но сам не проверял сие).

Update: хотя нет, это относилось к функциям с «Application.Volatile». Кажется .