[Iska]

Например, так:

читать дальше »

Код:

Option Explicit

Const SSFMOpenReadWrite = 1

Const strConsoleDataBlockSignature = "CC000000020000A0"
Const lngFontSizePosition          = 24


Dim objFSO
Dim objSpeechFileStream

Dim strLnkFileName
Dim lngConsoleDataBlockPosition

Dim arrContent


'strLnkFileName = "E:\Песочница\0063\Far2.lnk"
strLnkFileName = WScript.Arguments.Item(0)

Set objFSO                = WScript.CreateObject("Scripting.FileSystemObject")
Set objSpeechFileStream   = WScript.CreateObject("SAPI.spFileStream")

With objFSO
	If .FileExists(strLnkFileName) Then
		If UCase(.GetExtensionName(strLnkFileName)) = UCase("lnk") Then
			.GetFile(strLnkFileName).Copy strLnkFileName & ".bak", True
			
			With objSpeechFileStream
				.Open strLnkFileName, SSFMOpenReadWrite
				.Read arrContent, objFSO.GetFile(strLnkFileName).Size
				
				lngConsoleDataBlockPosition = InStr(ConvertByteArray2HexString(arrContent), strConsoleDataBlockSignature)
				
				If lngConsoleDataBlockPosition <> 0 Then
					.Seek lngConsoleDataBlockPosition \ 2 + Len(strConsoleDataBlockSignature) / 2 + lngFontSizePosition + 2
					.Write 28
				Else
					WScript.Echo "Can't find ConsoleDataBlock section in [" & strLnkFileName & "]"
				End If
				
				.Close()
			End With
		Else
			WScript.Echo "File [" & strLnkFileName & "] is not *.lnk file"
		End If
	Else
		WScript.Echo "File [" & strLnkFileName & "] not found"
	End If
End With

Set objSpeechFileStream   = Nothing
Set objFSO                = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
Function ConvertByteArray2HexString(arrByteArray)
	Dim i
	Dim strValue
	
	strValue = ""
	
	For i = 1 To LenB(arrByteArray)
		strValue = strValue & Right("00" & Hex(AscB(MidB(arrByteArray, i, 1))), 2)
	Next
	
	ConvertByteArray2HexString = strValue
End Function
'=============================================================================

Подразумевается, что в ярлыке задан TrueType шрифт.

[Iska]

Для cmd, ежели кто восхочет реализовать:
1. Найти в файле ярлыка сигнатуру из восьми байт «CC 00 00 00 02 00 00 A0». Если она найдена — значит в ярлыке наличествует секция «ConsoleDataBlock».
2. От начала найденной сигнатуры отсчитать (8+24+3) байта: размер самой сигнатуры (8 байт) плюс смещение внутри секции поля «FontSize» после сигнатуры (24 байта) плюс смещение нужного байта внутри поля; размер самого поля «FontSize» — четыре байта, нас, для TrueType шрифта, интересует 2-й байт

читать дальше »

(вообще-то, правильно — 3-й и 2-й байты [именно в таком, обратном, порядке; 1-й и 0-й байты используются, совместно с 3-им и 2-м байтами, при задании размера растровых шрифтов], но, думаю, вряд ли кто-то будет задавать размер шрифта для консольных приложений свыше 256 пикселей).

3. Для байта, полученному по этому смещению, задать потребный размер TrueType шрифта.

[Anton04]

Например, так: »

Я так понимаю, что .Write 28 это желаемый размер шрифта? А strLnkFileName = "E:\Песочница\0063\Far2.lnk" это путь к ярлыку?

Спасибо попробую и отпишусь.

P.S. А можно чтобы путь к ярлыку указывался вне скрипта? например чтоб можно было применить в cmd: my.vbs "%ALLUSERSPROFILE%\Рабочий стол\FAR manager.lnk"

[Iska]

Я так понимаю, что .Write 28 это желаемый размер шрифта? »

Да.

А strLnkFileName = "E:\Песочница\0063\Far2.lnk" это путь к ярлыку? »

Да, но эта строка в скрипте закомментирована:

Код:

'strLnkFileName = "E:\Песочница\0063\Far2.lnk"

Была оставлена «на пробу». А так путь к ярлыку берётся из первого параметра скрипта:

Код:

strLnkFileName = WScript.Arguments.Item(0)

Т.е., в командной строке можно вызывать именно так, как Вы написали:

чтоб можно было применить в cmd: my.vbs "%ALLUSERSPROFILE%\Рабочий стол\FAR manager.lnk" »

Anton04, Вы хотите менять размер шрифта в ярлыке сразу после установки Far Manager'а?

[Anton04]

Вы хотите менять размер шрифта в ярлыке сразу после установки Far Manager'а? »

Да конечно. А что это разве что-то меняет!? Я выбрал Фар как наиболее яркий пример...

P.S. Всё работает спасибо. Правда за-комментировал строку создания bak файла, т.к. мне не к чему.

[Iska]

Anton04, я не уверен, но, помнится, сразу после установки Far Manager'а в ярлыке указан растровый, не TrueType, шрифт. Скрипт надо будет менять.

комментировал строку создания bak файла, т.к. мне не к чему. »

На всякий случай: вдруг где что у меня не так .

[Anton04]

Iska,

Так, посмотрел, чё-то не нравится мне этот шрифт "Lucida Console" хочу "Точечные шрифты" и размером 10х18.
Поможете реализовать?

[Iska]

Anton04, я попробую почитать документацию на эту тему в ближайшие пару дней.

P.S. Я предпочитаю Consolas из последних версий Windows 7. Помнится, вроде как его можно получить с сайта Microsoft и сравнительно честно пользовать и под старыми ОС. Не пробовали?

[Anton04]

я попробую почитать документацию на эту тему в ближайшие пару дней. »

Буду ждать. Спасибо.

Я предпочитаю Consolas из последних версий Windows 7. Помнится, вроде как его можно получить с сайта Microsoft и сравнительно честно пользовать и под старыми ОС. Не пробовали? »

Посмотрел, но он тоже не очень, больно режет глаз, я даже скриншот сделал для сравнения (в верху точечный в низу Consolas).