CMD/BAT

El Sanchez · Конфигурация компьютера

gen0m.rsw,

Код:

Dir /B /S C:\*.EXT>>LIST.TXT

gen0m.rsw · Отправлено: **02:37, 07-09-2010** | #3

El Sanchez
Чуть-чуть не до понял!
Дело в том что файлы определенных имен и расширений!!!

gora · Конфигурация компьютера

Код:

@Echo Off
Set src=c:\

(For %%i In (
	File_1.EXT
	File_2.EXT
	File_3.EXT
) Do For /R "%src%" %%a In (%%i) Do If Exist "%%a" Echo %%a
)>LIST.TXT

NiOl · Отправлено: **12:24, 07-09-2010** | #5

Если файлы без пробелов внутри, то можно так:

Код:

dir C:\*.* /a-d /b /on /s | findstr "\file1 \file2 \file3"

* искомые файлы предваряем слешем, чтобы утилита не выдала, к примеру, файл "autofit.dat" на запрос "tofit.dat"

El Sanchez · Конфигурация компьютера

Цитата gen0m.rsw:

Дело в том что файлы определенных имен и расширений!!! »

Понятно. Тогда так:

Код:

Dir /B /S "C:\File_1.EXT" "C:\File_2.EXT" "C:\File_3.EXT">LIST.TXT

Цитата NiOl:

Если файлы без пробелов внутри »

NiOl, учитывать нужно все варианты, и с пробелами, и без. Поэтому вариант от gora может выглядеть вот так:

Код:

@Echo Off
Set src=c:\

(For %%i In (
	"File_1.EXT"
	"File_2.EXT"
	"File_3.EXT"
) Do For /R "%src%" %%a In (%%i) Do If Exist "%%~dpa%%~i" Echo %%~dpa%%~i
)>LIST.TXT

megaloman · Отправлено: **19:05, 07-09-2010** | #7

Прямолинейный, но удобочитаемый вариант

Код:

@Echo Off

Set Log=D:\file.log
del "%Log%"

Call :FindF "C:\" "Subst.exe"
Call :FindF "C:\" "Append.exe"
Call :FindF "C:\" "Attrib.exe"

GoTo :Eof

:FindF
FOR /F "usebackq delims=" %%i IN (`Dir "%~1%~2" /s /b`) DO echo %%i >>"%Log%"

gen0m.rsw · Отправлено: **02:55, 08-09-2010** | #8

El Sanchez
NiOl
megaloman

Всё окей!
Респект.