[mitiya]

Думаю как бы скопировать ключи реестра (меня оптьже волнуют пути к базам 1с7) из HKCU копируемых пользователей.
Не могу найти где они лежат.

[amel27]

как бы скопировать ключи реестра »

типа такого?.. тоже хватает минусов:
- сохраняются ключи целиком, а не отдельные параметры;
- в REG-файлах нужно еще как-то заменить "HKEY_USERS\TEMP" на "HKEY_CURRENT_USER"

Код:

@Echo Off
Set $Home=%~dp0
Set $Root=.

Set FileIncl=%$Home%FileIncl.txt
Set UserExcl=%$Home%UserExcl.txt
Set HKCUIncl=%$Home%HKCUIncl.txt

PushD %$Root%
If Exist users RD /S /Q users
MD Users
CD Users
For /F "Tokens=1,2" %%i In ('WMIC UserAccount Where LocalAccount^=True Get Name^,SID^,Status^|FindStr /IERC:"OK *"') Do Call :CopyUserProfile %%i %%j
PopD
Exit

:CopyUserProfile
 :: Сверка имени пользователя со списком исключения
 FindStr /IXC:"%1" %UserExcl%
 If Not ErrorLevel 1 GoTo :EOF
 CHCP 1251 >Nul
 :: Получение пути к профилю пользователя
 For /F "Tokens=1,2*" %%i In ('2^>Nul REG Query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\%2"^|FindStr /BIRC:" *ProfileImagePath"') Do Call Set $UserProfile=%%k
 If "%$UserProfile%"=="" GoTo :EOF
 :: Копирование файлов/каталогов по списку
 For /F "UseBackQ Tokens=* Delims=" %%A In ("%FileIncl%") Do If Exist "%$UserProfile%\%%A" XCopy /E/H/Q "%$UserProfile%\%%A" "%1\Files\%%A\"
 :: Копирование веток реестра по списку
 REG Load HKU\TEMP "%$UserProfile%\NTUSER.DAT" >Nul
 If ErrorLevel 1 GoTo :EOF
 For /F "UseBackQ Delims=" %%i In ("%HKCUIncl%") Do (
    @Echo F|XCopy /Q/R/V "%~dpnx0" "%1\Regis\%%i.reg" >Nul
    If Exist "%1\Regis\%%i.reg" DEL /Q/F "%1\Regis\%%i.reg"
    REG Export "HKU\TEMP\%%i" "%1\Regis\%%i.reg" /Y
 )
 REG Unload HKU\TEMP >Nul
 CHCP 866 >Nul
GoTo :EOF

[mitiya]

Application Data\1C\1Cv81\ibases.v8i скопировался в Application Data\1C\1Cv81\ibases.v8i\ibases.v8i плюс еще папки суда скопировались из папки 1Cv81.

это по прежнему актуально.
Так же не удается загрузить файл NTUSER.DAT когда пользователь вошел в систему, ну это логично конечно, но мне кажется должен быть способ подключится к его реестру если он вошел все равно.
Можно наверно конечно было бы исполнить команду по экспорту ключей от его имени, но тогда нужно где-то хранить пароли для всех пользователей.

[mitiya]

- в REG-файлах нужно еще как-то заменить "HKEY_USERS\TEMP" на "HKEY_CURRENT_USER" »

это как раз не проблема, есть такая прога CHGSTR.EXE , она может производить замену текста в файлах.

Кстати я так понял что подключенные-то пользователи как раз появляются в user со своим сидом , так что нужно как-то только проверить подключен ли он сейчас , наверно можно с помощью errorlevel после

REG Load HKU\TEMP "%$UserProfile%\NTUSER.DAT" >Nul »

[amel27]

это по прежнему актуально »

исправил

я так понял что подключенные-то пользователи как раз появляются в user со своим сидом , так что нужно как-то только проверить подключен ли он сейчас , наверно можно с помощью errorlevel »

где-то так (пока без замены), исправил ошибки, тестируйте:

Код:

@Echo Off
Set $Home=%cd%
Set $Root=.

Set FileIncl=%$Home%FileIncl.txt
Set UserExcl=%$Home%UserExcl.txt
Set HKCUIncl=%$Home%HKCUIncl.txt

PushD %$Root%
If Exist users RD /S /Q users
MD Users
CD Users
For /F "Tokens=1,2" %%i In ('WMIC UserAccount Where LocalAccount^=True Get Name^,SID^,Status^|FindStr /IERC:"OK *"') Do Call :CopyUserProfile %%i %%j
PopD
Exit

:CopyUserProfile
:: -------------
:: %1 - User Name
:: %2 - User SID
:: -------------
 CHCP 1251 >Nul
:: Сверка имени со списком исключения
 FindStr /IXC:"%~1" %UserExcl%
 If Not ErrorLevel 1 GoTo :EOF
:: Получение пути к профилю пользователя
 Set $UserProfile=
 For /F "Tokens=1,2*" %%i In ('2^>Nul REG Query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\%~2"^|FindStr /BIRC:" *ProfileImagePath"') Do Call Set $UserProfile=%%k
 If "%$UserProfile%"=="" GoTo :EOF
:: Копирование файлов/каталогов по списку
 For /F "UseBackQ Tokens=* Delims=" %%A In ("%FileIncl%") Do Call :CopyUserFile "%$UserProfile%\%%A" "%~1\Files\%%A"
:: Копирование веток реестра по списку
 REG Load HKU\TEMP "%$UserProfile%\NTUSER.DAT" >Nul 2>&1
 If Not ErrorLevel 1 (
    Call :CopyUserRegKeys "%~1" "HKU\TEMP"
    REG Unload HKU\TEMP >Nul
 )
 REG Query "HKU\%~2" >Nul 2>&1
 If Not ErrorLevel 1 Call :CopyUserRegKeys "%~1" "HKU\%~2"

 CHCP 866 >Nul
GoTo :EOF

:CopyUserFile
:: ----------------------------
:: %1 - Source File/Directory
:: %2 - Destination File/Folder
:: ----------------------------
 If Exist "%~1\" XCopy /E/H/Q "%~1" "%~2\" >Nul
 If Not Exist "%~1" GoTo :EOF
 @Echo F|XCopy /H/Q "%~1" "%~2" >Nul
GoTo :EOF

:CopyUserRegKeys
:: ------------------
:: %1 - User Name
:: %2 - Registry Hive
:: ------------------
 For /F "UseBackQ Delims=" %%i In ("%HKCUIncl%") Do (
    @Echo F|XCopy /R/V/Q "%~dpnx0" "%~1\Regis\%%i.reg" >Nul
    If Exist "%~1\Regis\%%i.reg" DEL /Q/F "%~1\Regis\%%i.reg"
    REG Export "%~2\%%i" "%~1\Regis\%%i.reg" >Nul 2>&1
 )
GoTo :EOF

[mitiya]

если вношу в список исключения пользователя Администратор , то он все равно копируется. Подозреваю что это из-за того что он пишется по русски, но CHCP 1251 вроде как есть , не понятно.