[Iska]

Konstantinkn, тогда уж тупо пользовать какой-нибудь WinMerge:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFile01=%~1
set sSourceFile02=%~2

if not defined sSourceFile01 (
	echo Usage: "%~nx0" ^<Source file 1^> ^<Source file 2^>
	exit /b 1
) else (
	if not defined sSourceFile02 (
		echo Usage: "%~nx0" ^<Source file 1^> ^<Source file 2^>
		exit /b 1
	) else (
		if not exist "%sSourceFile01%" (
			echo Not found source file [%sSourceFile01%].
			exit /b 2
		) else (
			if not exist "%sSourceFile02%" (
				echo Not found source file [%sSourceFile02%].
				exit /b 2
			)
		)
	)
)

set sPath2FFProbe=%ProgramFiles%\FFmpeg\bin\ffprobe.exe
set sFFProbeParameters=-v 32 -print_format default -show_format -show_streams -hide_banner
set sPath2WinMerge=%ProgramFiles(x86)%\WinMerge\WinMergeU.exe

set sLeftFile=%Temp%\LeftFile.txt
set sRightFile=%Temp%\RightFile.txt
 
>"%sLeftFile%"  "%sPath2FFProbe%" %sFFProbeParameters% "%sSourceFile01%"
>"%sRightFile%" "%sPath2FFProbe%" %sFFProbeParameters% "%sSourceFile02%"

"%sPath2WinMerge%" /e /u /wl /wr /maximize "%sLeftFile%" "%sRightFile%"

>nul del /f /q "%sLeftFile%" "%sRightFile%"

endlocal
exit /b 0

[Konstantinkn]

Iska, спасибо. Взял в изучение.

Iska, прошу, напишите в коде комментарии.

[Iska]

Konstantinkn, к сожалению, пакетные файлы поддерживают ограниченное комментирование. Но Вы можете спросить, ежели что-то непонятно конкретное.

[Konstantinkn]

Konstantinkn, к сожалению, пакетные файлы поддерживают ограниченное комментирование. Но Вы можете спросить, ежели что-то непонятно конкретное. »

Ясно. Спасибо, Iska.

А как сделать, чтобы в дополнение к Вашему решению происходило так:

3. Если все строки совпадают, bat-файл создаёт текстовый файл report.txt, и в нём написано: различий нет.
4. Если какие-либо строки различаются, bat-файл создаёт текстовый файл report.txt, и в нём написано: есть следующие различия: у файла file2.mp4 отличаются следующие строки: и список строк из файла file2.mp4, которые отличаются от строк файла file1.mp4

[Iska]

Konstantinkn, сделать можно. Но не вижу практического смысла.

[greg zakharov]

к сожалению, пакетные файлы поддерживают ограниченное комментирование

Konstantinkn, Iska лукавит, ему просто влом расписывать написанное.

Код:

@echo off
  setlocal
    rem традиционный комментарий
    set "var=переменная" % rem это послестрочный комментарий
    goto:end_comment
       а это многострочный комментарий
       ограниченный инструкцией goto и меткой end_comment
    :end_comment
  endlocal
exit /b

внеблочные комментарии могут быть размещены в любом месте
после инструкции exit /b основного блока

[Iska]

greg zakharov, флаг в руки, коллега, флаг в руки . Но лукавите Вы, именуя комментариями то, что ими не является. И Вы сие знаете.

[greg zakharov]

Iska, что именно не является комментарием? Всё приведенное - комментарии, только похоже вы об этом не знали. Жаль, жаль...

[Elven]

greg zakharov, rem или :: предназначены как раз для комментирования, здесь не спорю, а вот насчет других способова - соглашусь с Iska. Это как с холодным оружием: "Является холодным оружием" и "Может быть использовано в качестве холодного оружия" - разные вещи. Так же и тут, обычные строки могут быть использованы в качестве комментария будучи вырезаны из выполнения посредством безусловного перехода или отделены посредством eixt /b, но сами по себе они не являются комментариями. в противном случае нижеприведенный фрагмент тоже можно считать комментарием:

Код:

echo "Здесь мог быть ваш комментарий" > NUL