[DJ Mogarych]

Код:

powershell -command "((gc C:\temp\1.txt) -match 'slovo').Substring(6) > C:\temp\2.txt"

[YuS_2]

Можно ли эти скрипты объединить в один, чтобы не запускать два батника. А также чтобы в конечном результате file2.txt перезаписывался, а не дописывался. »

powershell

Код:

$file = 'file1.txt'
$arr = gc $file -enc OEM
$arr|?{$_ -notmatch 'slovo'}|%{$_ -replace '^.{6}'}|out-file $file -enc OEM

[megaloman]

Первый файл останется неизменным

Код:

@Echo Off
	Set "FileIn=Z:\Box_In\1.txt"
	Set "FileOut=Z:\Box_Out\2.txt"
	Set "Word=sLoVo"
	Set /A N=6

	>"%FileOut%" (For /F "usebackq delims=" %%s In (`2^>nul FINDSTR /I /C:"%Word%" "%FileIn%"`) Do (
		Set "String=%%s"
		(Call Echo %%String:~%N%%%)
	))
Exit /B 0

Первый файл будет содержать только выбранные строки, как в Ваших предыдущих скриптах

Код:

@Echo Off
	Set "FileIn=Z:\Box_In\1.txt"
	Set "FileOut=Z:\Box_Out\2.txt"
	Set "Word=sLoVo"
	Set /A N=6

	2>nul Del "%FileIn%.tmp" 
	>"%FileOut%" (For /F "usebackq delims=" %%s In (`2^>nul FINDSTR /I /C:"%Word%" "%FileIn%"`) Do (
		Set "String=%%s"
		>>"%FileIn%.tmp" (Echo %%s)
		(Call Echo %%String:~%N%%%)
	))
	>nul Move /Y "%FileIn%.tmp" "%FileIn%"
Exit /B 0

Выделены отличия первого скрипта от второго

[temphard]

Первый файл останется неизменным »

Первый файл будет содержать только выбранные строки, как в Ваших предыдущих скриптах »

Шикарно! Спасибо.
P.S. За powershell я тоже благодарен, но в данном случае мне именно батник нужен.

[DJ Mogarych]

temphard, код, который я привёл - это для батника.