CMD/BAT - запись ping в файл команда в одну строку...

Iska · Отправлено: **19:55, 07-02-2013** | #2

White-Lion, используйте для открытия файла приложение, понимающее OEM/866, например Notepad++. Я пользуюсь Far Manager'ом.

gora · Конфигурация компьютера

Цитата White-Lion:

чтобы окно не закрывалось »

Переменная цикла в батнике должна быть с двумя знаками процента:

Код:

for /l %%i in (0,0,1) do echo.|set/p=%TIME:~0,8% >> c:\pin.txt & ping -n 1 google.ru | findstr "Превышен Ответ" >> c:\pin.txt & ping -n 2 localhost > nul

White-Lion · Отправлено: **09:46, 08-02-2013** | #4

Цитата gora:

Переменная цикла в батнике должна быть с двумя знаками процента: »

прописал....

Все осталось на прежнем месте.

Dragokas · Отправлено: **14:42, 21-02-2013** | #5

Попробуйте так:

Код:

@echo off
SetLocal EnableDelayedExpansion
set FileOut=c:\pin.txt
if exist "%FileOut%" del /f "%FileOut%"

:begin
chcp 866> nul
for /f "delims=" %%a in ('ping -n 1 google.ru ^|findstr "Превышен Ответ"') do (
  chcp 1251> nul
  set /p=!TIME:~0,8! >> "%FileOut%" <nul
  call :convert "%%a" 2>NUL
  ping 127.1 -n 2 >nul
)
goto :begin
 
:convert
echo.%~1>>"%FileOut%"

или однострочный через Unicode:

Код:

@cmd /Q /V:ON /C "for /L %%a in (0,0,0) do set/p=!TIME:~0,8! >c:\t.txt <nul& ping -n 1 google.ru| findstr "Превышен Ответ">>c:\t.txt& CMD /U /C type c:\t.txt>> c:\pin.txt"

сохранять в кодировка OEM-866.
P.S. Подправил код с динамическим изменением времени.

Smer4 · Отправлено: **18:10, 05-04-2015** | #6

Код:

@cmd /Q /V:ON /C "for /L %%a in (0,0,0) do set/p=!TIME:~0,8! >c:\t.txt <nul& ping -n 1 google.ru| findstr "Превышен Ответ">>c:\t.txt& CMD /U /C type c:\t.txt>> c:\pin.txt"

Ребят при запуске batника вот такую ошибку получаю. Как при запуске от администратора через райт клик, так и просто по дабл клику. В свойствах файла выставить галку " запускать от имени администратора " невозможно.

Задача у меня схожая с автором темы
запись команды ping в файл с указанием времени ( для определения временных границ когда интернет обрывается ) .

Georgio · Отправлено: **21:44, 05-04-2015** | #7

Код:

@>"C:\pin.txt" (
 for /l %%i in () do @>nul chcp 866& ping -n 1 google.ru| findstr/i "Превышен Ответ"|(
 for /f "delims=" %%j in ('more') do @>nul chcp 1251& cmd/v/c "echo.!time:~0^,8! %%j")
)

или

Код:

@>"C:\pin.txt" (for /l %%i in () do @>nul chcp 866& ping -n 1 google.ru| findstr/i "Превышен Ответ"| for /f "delims=" %%j in ('more') do @>nul chcp 1251& cmd/v/c "echo.!time:~0^,8! %%j")

(в одну строку).

Пакетный файл сохранить в кодировке "OEM-866" и запускать от имени администратора.

Georgio · Отправлено: **12:03, 06-04-2015** | #8

Из личного сообщения:

Цитата Smer4:

Всё та же ошибка в окне cmd . 2 вариант в 1 строку , при первом варианте открывается пустое окно cmd файл pin.txt создается, но он тоже пустой.

.

Smer4, теперь всё понятно: дело не в кодах.

Нельзя называть пакетные файлы именами, совпадающими с какими-либо командами.

Переименуйте Ваш пакетный файл "ping.bat" (или "ping.cmd"), например, в "пинг.bat" (или "пинг.cmd") и, как говорится, будет Вам счастье.