CMD/BAT - [решено] Замена строк в файле, содержащем пустые строки

Iska · Отправлено: **02:06, 02-03-2015** | #2

Уберите:

Цитата SharkyEXE:

при помощи *.bat или *.cmd файла »

и будет Вам счастье.

Georgio · Отправлено: **04:32, 02-03-2015** | #3

Код:

@echo off& setlocal

set "file=2015-03-02.txt"
set "label=Alt Line Fill"
set "delim=="
set "substitute=0"

>1.tmp (
type "%file%"
echo.
)
for /f %%i in ('^<1.tmp find/c /v ""') do<1.tmp>2.tmp (
 for /l %%j in (1 1 %%i) do (
  set/p "x="
  if defined x (
   for /f "delims=%delim%" %%k in ('cmd/v/c echo.!x!') do (
    if "%%k" equ "%label%" (
     cmd/v/c echo.!label!!delim!!substitute!
    ) else (
     cmd/v/c echo.!x!
    )
    )
   set "x="
  ) else (
   echo.
  )
  )
 )
>nul chcp 1251
<nul>"%file%" (
set/p=яю
cmd/u/c type 2.tmp
)
del 1.tmp 2.tmp

endlocal& exit/b 0

Пакетный файл должен быть в кодировке Win-1251 (ANSI, кириллица)!

SharkyEXE · Отправлено: **07:33, 02-03-2015** | #4

Цитата Iska:

будет Вам счастье. »

Извините меня, пожалуйста, я Вас не понимаю.
Не хочу ни кого обидеть, извините меня, пожалуйста, локально для меня счастье - это 100%но рабочий код :-)

Georgio
Здравствуйте.

А нельзя, ли, пожалуйста, Ваш вариант сделать универсальным:
1) если файл 2015-03-02.txt имеет кодировку Win 1251 (ANSI - кириллица), то в Вашем коде комментируются одни строки, раскомментируются другие строки
2) если файл 2015-03-02.txt имеет кодировку Win 866 (OEM - русская), то в Вашем коде комментируются одни строки, раскомментируются другие строки

Просто лично мне очень хочется универсальности, чтобы Ваш код работал с любой кодировкой файла 2015-03-02.txt.
Или такая универсальность не получится?
Так сказать, чтобы для каждой кодировки файла 2015-03-02.txt не писать заново Ваш код

Спасибо.

Georgio · Отправлено: **14:38, 02-03-2015** | #5

SharkyEXE, здравствуйте.

Цитата SharkyEXE:

Просто лично мне очень хочется универсальности, чтобы Ваш код работал с любой кодировкой файла 2015-03-02.txt.
Или такая универсальность не получится? »

Такую, как Вы описали, универсальность сделать можно. Более того, Вам не придётся ничего "закомментировывать", поскольку пакетный файл будет сам условно определять кодировку текстового файла из перечисленных Вами. Но только не расширяйте Ваш список кодировок

.

SharkyEXE, проверяйте:

Код:

@echo off& setlocal

set "file=2015-03-02.txt"
set "label=Alt Line Fill"
set "delim=="
set "substitute=0"

>1.tmp type "%file%"
for /f %%i in ('^<1.tmp find/c /v ""') do<1.tmp>2.tmp (
 for /l %%j in (1 1 %%i) do (
  set/p "x="
  if defined x (
   for /f "delims=%delim%" %%k in ('cmd/v/c echo.!x!') do (
    if "%%k" equ "%label%" (
     cmd/v/c echo.!label!!delim!!substitute!
    ) else (
     cmd/v/c echo.!x!
    )
    )
   set "x="
  ) else (
   echo.
  )
  )
 )
>nul chcp 1251
>>2.tmp echo.
for /f "tokens=1,2 delims=|" %%i in ("%file%|1.tmp") do>"%file%" (
 if %%~zi neq %%~zj (
  <nul set/p=яю
  >nul chcp 866
  cmd/u/c type 2.tmp
 ) else (
  type 2.tmp
 )
 )
del 1.tmp 2.tmp

endlocal& exit/b

.

SharkyEXE · Отправлено: **15:10, 02-03-2015** | #6

Georgio
Здравствуйте.

Пожалуйста, если у Вас есть время, возможность, желание - при написания Вами этого кода Вы на какие кодировки для файла 2015-03-02.txt ориентировались?

Это:
1) Win 1200 (UTF-16LE)
2) Win 1251 (ANSI - кириллица)
3) Win 866 (OEM - русская)
или как?

И еще: файл *.bat или *.cmd, содержащий этот код, в какой должен быть кодировке?

Спасибо.

Georgio · Отправлено: **15:42, 02-03-2015** | #7

Цитата SharkyEXE:

Это:
1) Win 1200 (UTF-16LE)
2) Win 1251 (ANSI - кириллица)
3) Win 866 (OEM - русская)
или как? »

Это!

Цитата SharkyEXE:

И еще: файл *.bat или *.cmd, содержащий этот код, в какой должен быть кодировке? »

Цитата Georgio:

Пакетный файл должен быть в кодировке Win-1251 (ANSI, кириллица)! »