[ratibor79]

pogo,

Вот готовый скрипт, который я подшаманил и использую у себя на работе.

Код:

On Error Resume Next
Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)
strRegard = "Best regards,"
strBlank =""
'Получаем полное имя
strName = objUser.FullName
'Должность
strTitle = objUser.Title
'Подразделение
strDepartment = objUser.Department
'Компания
strCompany = objUser.Company
'Номер телефона
strPhone = objUser.telephoneNumber
'Сотовый
strMobile = objUser.mobile
'Факс
strFax = objuser.facsimileTelephoneNumber
'Получаем почтовый индекс
strPostIndex = ObjUser.postalCode
'Город
strCity = objuser.l
'Улица
strStreet = objuser.streetAddress
'адрес электронной почты
strEmail = objuser.mail
'WEB страница
strWeb = objuser.wWWHomePage
'Логотип организации
strLogo = "\\Server1\Shared\LOGO\logo.jpg"
'Логотип Facebook
strFacebook = "\\Server1\Shared\LOGO\Facebook.jpg"
'Логотип ВКортакте
strVKontakte = "\\Server1\Shared\LOGO\VKontakte.jpg"
'Логотип INSTAGRAM
strInstagram = "\\Server1\Shared\LOGO\Instagram.jpg"
'Логотип TWITTER
strTwitter = "\\Server1\Shared\LOGO\Twitter.jpg"
'Логтип YouTube 
strYouTube = "\\Server1\Shared\LOGO\YouTube.jpg"

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature
Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'СОЗДАЕМ САМУ ПОДПИСЬ
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

'Начертаниен шрифта
objSelection.Font.Bold = False
'Шрифт
objSelection.Font.Name = "Tahoma"
'Размер
objSelection.Font.Size = "11"
'Цвет, можно указывать в десятичном или RGB формате, тогда: RGB(0, 55, 110)
objSelection.Font.Color = RGB(89, 89, 89)

'Формат
objSelection.TypeText strRegard
objSelection.TypeText CHR(11)

'пустая строка
objSelection.Font.Size = "7,5"
objSelection.TypeText strBlank
objSelection.TypeText CHR(11)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Начертание шрифта
objSelection.Font.Bold = True
'Шрифт
objSelection.Font.Name = "Tahoma"
'Размер
objSelection.Font.Size = "10"
'Цвет, можно указывать в десятичном или RGB формате, тогда: RGB(0, 55, 110)
objSelection.Font.Color = RGB(255, 128, 0)

'Вставляем полное имя
objSelection.TypeText strName
objSelection.TypeText CHR(11)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Начертание шрифта
objSelection.Font.Bold = True
'Шрифт
objSelection.Font.Size = "10"
'Цвет, можно указывать в десятичном или RGB формате, тогда: RGB(0, 55, 110)
objSelection.Font.Color = RGB(89, 89, 89)
'Должность
objSelection.TypeText strTitle
objSelection.TypeText CHR(11)
'Подразделение
'''objSelection.TypeText strDepartment
'''objSelection.TypeText CHR(11)

'Наименование Компании
objSelection.TypeText strCompany
objSelection.TypeText CHR(11)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Шрифт
objSelection.Font.Size = "7,5"

'пустая строка
objSelection.TypeText strBlank
objSelection.TypeText CHR(11)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Начертание шрифта
objSelection.Font.Bold = False
'Уменьшаем размер шрифта для адреса
objSelection.Font.Size = "7,5"
'Изменяем цвет для адреса электронной почты и сайта
objselection.font.color = RGB(89, 89, 89)

'Почтовый адрес: дом, улица
objSelection.TypeText strStreet
objSelection.TypeText CHR(11)

'Почтовый адрес: индекс, город, страна.
objSelection.TypeText strPostIndex & ", " & strCity & ", Kazakhstan"
objSelection.TypeText CHR(11)

'Телефон
objSelection.TypeText "Telephone: " & strPhone ' доб. & strIntPhone
objSelection.TypeText CHR(11)

'Сотовый
objSelection.TypeText "Cell Phone: " & strMobile
objSelection.TypeText CHR(11)

'Факс
'''objSelection.TypeText "Факс " & strFax
'''objSelection.TypeText CHR(11)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'ДОБОВЛЯЕМ ССЫЛКИ

'Изменяем цвет для адреса электронной почты и сайта
objselection.font.color = RGB(0, 0, 255)

'Вставляем адрес почты
Set hyp = objSelection.Hyperlinks.Add(objSelection.Range, "mailto:" & strEmail, , , strEmail)
hyp.Range.Font.Size = "7,5"
objSelection.TypeText CHR(11)

'корпоративный сайт
Set hyp = objSelection.Hyperlinks.Add(objSelection.Range, strWeb, "", "", strWeb)
hyp.Range.Font.Size = "7,5"
objSelection.TypeText CHR(11)

'пустая строка
objSelection.TypeText strBlank
objSelection.TypeText CHR(11)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'ДОБОВЛЯЕМ ЛОГОТИПЫ

'логотип компании
objSelection.InlineShapes.AddPicture(strLogo)
objDoc.Hyperlinks.Add objDoc.InlineShapes.Item(1), "http://www.oszone.ru"

'пустая строка
objSelection.TypeText strBlank
objSelection.TypeText CHR(11)

'пустая строка
objSelection.TypeText strBlank
objSelection.TypeText CHR(11)

'логотип Facebook
objSelection.TypeText " "
objSelection.InlineShapes.AddPicture(strFacebook)
objDoc.Hyperlinks.Add objDoc.InlineShapes.Item(2), "https://www.facebook.com/oszone"
'логотип ВКонтакте
objSelection.TypeText " "
objSelection.InlineShapes.AddPicture(strVKontakte)
objDoc.Hyperlinks.Add objDoc.InlineShapes.Item(3), "http://vk.com/oszone"
'логотип Instagram
objSelection.TypeText " "
objSelection.InlineShapes.AddPicture(strInstagram)
objDoc.Hyperlinks.Add objDoc.InlineShapes.Item(4), "http://instagram.com/oszone"
'логотип Twitter
objSelection.TypeText " "
objSelection.InlineShapes.AddPicture(strTwitter)
objDoc.Hyperlinks.Add objDoc.InlineShapes.Item(5), "https://twitter.com/oszone"
'логотип Twitter
objSelection.TypeText " "
objSelection.InlineShapes.AddPicture(strYouTube)
objDoc.Hyperlinks.Add objDoc.InlineShapes.Item(6), "https://www.youtube.com/channel/oszone"

Set objSelection = objDoc.Range()

objSignatureEntries.Add "Corp. Signature", objSelection
objSignatureObject.NewMessageSignature = "Corp. Signature"
objSignatureObject.ReplyMessageSignature = "Corp. Signature"

objDoc.Saved = True
objDoc.Close
objWord.Quit

Здесь есть Логотип компании + логотипы популярных соц. сетей с гиперссылками. Естественно в скрипте указаны условные ссылки на ресурсы.

Попробуйте. Переделайте под себя.

Как-то так

[pogo]

ratibor79,
Большое спасибо!! Очень информативный скрипт.
А то я уже вставил руками в подпись .jpeg, нашёл где лежат эти подписи, там в .htm нашёл кусок кода, который отвечает за картинку и начал думать как вставить этот кусок htm кода в vbs скрипт

[zorroql]

Решил воспользоваться данным скриптом но возникли вопросы:
Как можно изменить место положения логотипа компании?
Как сделать вертикальную разделительную черту между ФИ.О должность,название компании
Подскажите пожалуйста как реализовать данную схему ?