[Iska]

Нужно чтобы каждую пятницу в 17-00 »

Планировщик/Назначенные задания.

удалял файлы Х1.у и Х2.у из директории Z »

читать дальше »

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFolder=E:\Песочница\0404\02

set sFiles="0001.txt" "0003.txt"

if exist "%sSourceFolder%\." (
	for %%i in (%sFiles%) do if exist "%sSourceFolder%\%%~i" echo del /f /q "%sSourceFolder%\%%~i"
) else (
	echo Can't find source folder [%sSourceFolder%].
	exit /b 2
)

endlocal
exit /b 0

Для реального удаления уберите «echo».

[spamrzn@vk]

благодарствую

[Georgio]

Iska, а почему не

Код:

if exist "%sSourceFolder%\." (
 pushd "%sSourceFolder%"
 del /f /q %sFiles%
 popd
 ) else (

?

[Iska]

Georgio, запросто. Можно и:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFolder=E:\Песочница\0404\02

set sFiles="0001.txt" "0003.txt"

2>nul pushd "%sSourceFolder%" && (
	2>nul del /f /q %sFiles%
	popd
) || (
	echo Can't find source folder [%sSourceFolder%].
	exit /b 2
)

endlocal
exit /b 0

Кому как нравится. Ну, и — от условий может зависеть, конечно.