[Iska]

vogon_, во-первых, не используйте системные и пользовательские переменные в качестве рабочих:

Код: set path=system/priv-app/SecSettings.apk=com.android.settings »

Во-вторых:

Ожидаемый результат - system/priv-app/, »

совершенно не ожидаемый. Ожидаемый:

Код:

system/priv-app/&rem .apk=com.android.settings

В чём может быть проблема? »

В «&».

Опишите, что потребно получить. А не как.

[Georgio]

Код:

set apkName=SecSettings
set path=system/priv-app/SecSettings.apk=com.android.settings

call set "path=%%path:%apkName%=&rem %%"
echo %path%

[megaloman]

Georgio, Красивая конструкция, но, Насколько я понял, обрезать строку не получилось, результат - обрезанная выдача искаженной исходной строки? Если сделать echo "%path%" можно это увидеть? Тогда непонятно: в чём задача?

[vogon_]

Iska, ответ на первое замечание - спасибо, учту на будущее

На второе - ожидаемый результат тот, который я указал, не иначе. По-крайней мере, я ожидал такой результат.

На третье - так ведь указано. Объясню подробнее (я неясно выразился, прошу прощения) - нужно в строке path откинуть все символы после подстроки apkName с этой подстрокой включительно.

Ответ на мой вопрос дал Georgio, поэтому всё решено

Georgio, спасибо, всё работает
Только в начале почему-то добавляется знак процента. А так всё супер! Благодарю)

megaloman, комментарием выше я написал, в чём задача (правда, она уже решена).
Спасибо за внимание, очень приятно, что так много отзывчивых людей! Удачи)

[Iska]

Ответ на мой вопрос дал Georgio, поэтому всё решено Georgio, спасибо, всё работает »

Отнюдь:

Код:

set apkName=SecSettings
set path=system/priv-app/SecSettings.apk=com.android.settings

call set "path=%%path:%apkName%=&rem %%"
echo [%path%]

Код: E:\Песочница\0382>0007.cmd E:\Песочница\0382>set apkName=SecSettings E:\Песочница\0382>set path=system/priv-app/SecSettings.apk=com.android.settings E:\Песочница\0382>call set "path=%path:SecSettings=&rem %" E:\Песочница\0382>echo [system/priv-app/ & rem .apk=com.android.settings] [system/priv-app/

Переменная окружения содержит всю строку «system/priv-app/&rem .apk=com.android.settings». В этом легко убедиться, хотя бы исполнив «set path». Просто командный процессор при выводе переменной окружения по «echo» рассматривает «&» как специальный символ.

нужно в строке path откинуть все символы после подстроки apkName с этой подстрокой включительно. »

Следует воспользоваться рецептом от коллеги gora:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sVar=bla-bla-bla-substring-bla-bla-bla
set sSubString=substring

set sLastPartVar=!sVar:*%sSubString%=!
set sResultVar=!sVar:%sLastPartVar%=!

echo [%sResultVar%]

endlocal
exit /b 0

[Georgio]

Код:

set apkName=SecSettings
set path=system/priv-app/SecSettings.apk=com.android.settings

call set "path=%%path:%apkName%=&rem %%"
for /f "delims=" %%i in ('call echo %%path%%') do set path=%%i
echo %path%

[vogon_]

Iska, но ведь у меня всё работает:

Код:

C:\>set apkName=SecSettings

C:\>set path=system/priv-app/SecSettings.apk=com.android.settings

C:\>call set "path=%path:%apkName%=&rem %"

C:\>echo %path%
system/priv-app/

Это тот результат, который я ожидал и который мне очень нужен.
В чём проблема? Дело в том, что после "&rem " всё делается комментарием, в этом фишка такой команды) То есть при использовании переменной path та часть, которая после знака комментария, не будет учитываться.

Как бы там ни было, переменная имеет то значения, которое я хотел достать.
Спасибо за помощь)

[gora]

Как бы там ни было, переменная имеет то значения, которое я хотел достать. »

Нет, Вы не правы! Переменная как раз имеет другое значение, а именно то что приведено у Iska

E:\Песочница\0382>echo [system/priv-app/ & rem .apk=com.android.settings] [system/priv-app/ »

А строкой ниже приведена не переменная, а результат команды Echo с такой горе-переменной. Если она у Вас больше ни с какими командами не будет использоваться, то это полбеды, в противном случае содержимое переменной должно быть более легитимный и не должно использовать "фокусы" с & rem

[Iska]

Iska, но ведь у меня всё работает: »

Не верю:

Код: E:\Песочница\0382>0010.cmd E:\Песочница\0382>set apkName=SecSettings E:\Песочница\0382>set path=system/priv-app/SecSettings.apk=com.android.settings E:\Песочница\0382>call set "path=%path:SecSettings=&rem %" E:\Песочница\0382>echo [system/priv-app/ & rem .apk=com.android.settings] [system/priv-app/

Покажите мне вывод того же кода, но с добавлением «[]» и «set path»:

Код:

set apkName=SecSettings
set path=system/priv-app/SecSettings.apk=com.android.settings

call set "path=%%path:%apkName%=&rem %%"
echo [%path%]
set path

В чём проблема? Дело в том, что после "&rem " всё делается комментарием, в этом фишка такой команды) То есть при использовании переменной path та часть, которая после знака комментария, не будет учитываться. »

Проблема в том, что переменная окружения содержит совсем не то, что Вы видите. И эта, невидимая Вам, часть учитывается.

Georgio, код из #7 отрабатывает корректно.