[Iska]

WSH:

Код:

Option Explicit

Dim objWord

With WScript.CreateObject("WScript.Network")
	WScript.Echo "Computer name: " & .ComputerName
	WScript.Echo "User name: "     & .UserDomain & "\" & .UserName
End With

On Error Resume Next
Set objWord = WScript.CreateObject("Word.Application")

If Err.Number = 0 Then
	On Error Goto 0
	WScript.Echo "Microsoft Office version: " & objWord.Build
	objWord.Quit
	
	Set objWord = Nothing
Else
	Err.Clear
	On Error Goto 0
	WScript.Echo "Microsoft Office version: Not found"
End If

With WScript.CreateObject("InternetExplorer.Application")
	WScript.Echo "Internet Explorer version: " & WScript.CreateObject("Scripting.FileSystemObject").GetFileVersion(.FullName)
	.Quit
End With

WScript.Quit 0

Это не единственный способ.

[Crush45]

Спасибо, но я ничего тут не понимаю) Мне bat-синтаксис роднее.

[Iska]

Crush45, укажите путь, куда делать вывод в файл — я приведу детали «как».

[Crush45]

Ну пусть будет D:\Microversion\*.log - путь я заменю. Ваяю пока на батнике свою версию с распарсиванием реестра. Геморно конечно, но по другому пока не умею.
Вопрос таков, а можно ли это все сгрузить в какую-либо SQL-базу?

Допустим пусть база будет с одной таблицей - в ней столбцы: номер записи, имя компа, пользователь, версия ie, office + по возможности Windows?

[sunnykey]

Код:

#Powershell script.
#Don't forget unlock script executing by 
#using command "Set-ExecutionPolicy RemoteSigned" or "Set-ExecutionPolicy Unrestricted"
#Save this file with ".ps1" extension
$log="d:\ie_office.log"
$str=$env:COMPUTERNAME+"`t"
Get-WmiObject -Query "SELECT * FROM Win32_Product WHERE Name LIKE 'Microsoft Office%'" | `
    Select-Object -First 1 | % {$str+=$_.Name+"`t"}
$str+="IE Ver"+[System.Diagnostics.FileVersionInfo]::GetVersionInfo(
    "C:\Program Files\Internet Explorer\iexplore.exe").ProductVersion.ToString()
$str | Out-File -FilePath $log -Append
"`n"+"----------------------------------------------------------------------" | Out-File -FilePath $log -Append

Предлагаю свой вариант.

Вопрос таков, а можно ли это все сгрузить в какую-либо SQL-базу? »

Можно, но нужно читать мануалы

[Iska]

Вопрос таков, а можно ли это все сгрузить в какую-либо SQL-базу? »

Это самое правильное решение.

Вот примерная болванка:

читать дальше »

Код:

Option Explicit

Const adOpenStatic = 3
Const adLockOptimistic = 3
Const adCmdText = 1

Dim objDictionary

Dim objWord
Dim objSWbemObjectEx


Set objDictionary = WScript.CreateObject("Scripting.Dictionary")

With WScript.CreateObject("WScript.Network")
	objDictionary.Add "Computer name", .ComputerName
	objDictionary.Add "User name", .UserDomain & "\" & .UserName
End With

On Error Resume Next
Set objWord = WScript.CreateObject("Word.Application")

If Err.Number = 0 Then
	On Error Goto 0
	objDictionary.Add "Microsoft Office version", objWord.Build
	objWord.Quit
	
	Set objWord = Nothing
Else
	Err.Clear
	On Error Goto 0
	objDictionary.Add "Microsoft Office version", vbNull
End If

With WScript.CreateObject("InternetExplorer.Application")
	objDictionary.Add "Internet Explorer version", WScript.CreateObject("Scripting.FileSystemObject").GetFileVersion(.FullName)
	.Quit
End With

For Each objSWbemObjectEx In WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\cimv2").ExecQuery("SELECT Version FROM Win32_OperatingSystem WHERE Primary='True'")
	objDictionary.Add "OS version", objSWbemObjectEx.Version
Next

WScript.CreateObject("ADODB.Recordset").Open _
	"INSERT INTO [Sample table] (" & _
		"[DateTime], [Computer name], [User name], [OS version], [Microsoft Office version], [Internet Explorer version]" & _
	") VALUES (" & _
		"GETDATE(), " & _
		"'" & objDictionary.Item("Computer name") & "', " & _
		"'" & objDictionary.Item("User name") & "', " & _
		"'" & objDictionary.Item("OS version") & "', " & _
		"'" & objDictionary.Item("Microsoft Office version") & "', " & _
		"'" & objDictionary.Item("Internet Explorer version") & "'" & _
	")", "Provider=sqloledb;Data Source=SQL;Initial Catalog=SampleDatabase;Integrated Security=SSPI;", adOpenStatic, adLockOptimistic, adCmdText

objDictionary.RemoveAll
Set objDictionary = Nothing

WScript.Quit 0

где, «SQL» — имя SQL сервера, «SampleDatabase» — имя базы данных, «Sample table» — имя таблицы в указанной базе данных, «[DateTime], [Computer name], [User name], [OS version], [Microsoft Office version], [Internet Explorer version]» — поля указанной таблицы базы данных (я добавил кроме перечисленных Вами ещё и поле «DateTime» — дату и время внесения изменений).

[Crush45]

"INSERT INTO [Sample table] (" & _ »

Я так понимаю в данном случае нужно указать в какую таблицу базы писать?

[Iska]

Я так понимаю в данном случае нужно указать в какую таблицу базы писать? »

Да. Я так и думал, что что-то пропустил в описании. Добавил в предыдущий пост.

[Vadikan]

Crush45,
http://www.microsoft.com/sam/en/ca/msia.aspx
http://www.microsoft.com/sam/en/us/map.aspx