[Anonymоus]

Специмволы вообще экранируются через ^, но если неизвестно заранее, сколько их будет в строке - это не выход. Но если использовать вывод внутри цикла, то его особенностью будет то, что нахождение в считанной строке специмволов не повлияет на вывод. Пример:

Код:

@Echo Off
Set InFile=test.txt
Set OutFile=out.txt
For /F "usebackq delims=" %%A In ("%InFile%") Do (
	Echo %%A|Find "43">nul&&(
		Echo VarC=200>>"%OutFile%"
	)||(
		Echo.%%A>>"%OutFile%"
	)
)2>nul

Недостаток - если искомый паттерн ("43") будет в одной строке со спецсимволами, его Find не найдет.

[H1ghlander]

вроде работает. только есть одна проблема, если встречается пустая строка, то в новый файл записывается "Режим вывода команд на экран (ECHO) отключен."
как это можно исправить??

[Anonymоus]

H1ghlander, у меня на XP SP3 цикл for просто игнорирует пустые строки, не могу воспроизвести, увы. Но попробуйте заменить Echo %%A>>"%OutFile%" на

Код:

If Not "%%A"=="" (Echo %%A>>"%OutFile%") Else (Echo.>>"%OutFile%")

[H1ghlander]

Нет не помогает.
Сообщение появляется, только в том случае если перед переносом строки находится пробелы или знаки табуляции.

[El Sanchez]

H1ghlander, попробуйте так:

Код:

For /F "Tokens=1* Delims=:" %%A In ('Type "C:\12.txt"^|FindStr /in $') Do ((@Echo:"%%B"|Find "43" 1>nul&&@Echo:VarC=200)&(@Echo:"%%B"|Find /v "43" 1>nul&&@Echo:%%B))>>out.txt

[H1ghlander]

El Sanchez,
Твой вариант выводит только номера строк, да и причем всех подряд, в том числе где есть пусты строки

[Anonymоus]

H1ghlander, вот ещё такой вариант, в этом случае делает проверку, не является ли таб или пробел первым символом строки, если да - то пишет пустую строку. А вообще, это очень плохое решение, вам стоит помотреть в сторону sed (http://gnuwin32.sourceforge.net/packages/sed.htm)

Код:

@Echo Off
SetLocal EnableDelayedExpansion
Set InFile=test.txt
Set OutFile=out.txt
For /F "usebackq delims=" %%A In ("%InFile%") Do (
	Set String=%%A
	Echo %%A|Find "43">nul&&(
		Echo VarC=200>>"%OutFile%"
	)||(
		If Not "!String:~,1!"=="	" If Not "!String:~,1!"==" " Echo %%A>>"%OutFile%"
		If "!String:~,1!"=="	" Echo.>>"%OutFile%"
		If "!String:~,1!"==" " Echo.>>"%OutFile%"
	)
) 2>nul
pause

[El Sanchez]

Твой вариант выводит только номера строк, да и причем всех подряд, в том числе где есть пусты строки »

H1ghlander, неправда, но кавычки я пропустил . Исправил.

[CyberMuesli]

Код:

@echo off
setlocal enabledelayedexpansion

set A1=^<A^&B^>
set A1
echo A1=!A1!
echo !A1!>temp.tmp
type temp.tmp
del temp.tmp

C:>test.bat
A1=<A&B>
A1=<A&B>
<A&B>