[El Sanchez]

krbmoney,

Код:

@Echo Off
Set Source=C:\Source
For /R "%Source%" %%A In (*.txt) Do If Not Exist "%%~dpA_merged%%~xA" Copy /Y /B "%%~dpA*%%~xA" "%%~dpA_merged%%~xA"

и что буква /б значит кто-нибудь знает? »

Код:

copy /?
 /B           Файл является двоичным файлом.

[krbmoney]

El Sanchez, огромное спасибо!

а можно полученный файл оставить, а остальные удалить? или полученные файлы в какую-нить папку закинуть?

[El Sanchez]

а можно полученный файл оставить, а остальные удалить? »

krbmoney,

Код:

@Echo Off
SetLocal
Set Source=C:\Source
For /R "%Source%" %%A In (*.txt) Do (
	If Not Exist "%%~dpA_merged%%~xA" Copy /Y /B "%%~dpA*%%~xA" "%%~dpA_merged%%~xA"
	If /i Not "%%~nxA"=="_merged%%~xA" Del /F /Q "%%A" 2>nul
)

или полученные файлы в какую-нить папку закинуть? »

Код:

@Echo Off
SetLocal
Set Source=C:\Source
Set Output=C:\Output

PushD %Output%
For /R "%Source%" %%A In (*.txt) Do If /i Not "%%~dpA"=="%CD%\" If Not Exist "%%~dpA_merged%%~xA" Copy /Y /B "%%~dpA*%%~xA" "%%~dpA_merged%%~xA"
PopD
For /F "Tokens=1* Delims=:" %%A In ('Dir /B /S _merged.txt^|FindStr /in .') Do Move /Y "%%B" "%Output%\%%~nB_%%A%%~xB" 2>nul