CMD/BAT - [решено] Копирование папок и файлов по маскам

amel27 · Отправлено: **05:14, 19-01-2011** | #2

Код:

xcopy /q/s/y/r/h "%~dp0SP1rc2\*ru-ru*" "%~dp0LANG\"
xcopy /q/s/y/r/h "%~dp0SP1rc2\*en-us*" "%~dp0LANG\"

dorosa · Отправлено: **12:23, 19-01-2011** | #3

amel27,
Такую команду побывал, файлы копируются, а папки только те, где есть файлы соответствующие маскам *ru-ru* и *en-us*.
А нужно, чтобы копировались и папки *ru-ru* и *en-us*.

amel27 · Отправлено: **12:53, 19-01-2011** | #4

Цитата dorosa:

нужно, чтобы копировались и папки *ru-ru* и *en-us*»

добавить обработку папок:

Код:

@echo off
SETLOCAL EnableDelayedExpansion

for /f "delims=" %%a in ('dir /b/s/ad "%~dp0SP1rc2\*ru-ru*" "%~dp0SP1rc2\*en-us*"') do (set "$a=%%a"
md "!$a:%~dp0SP1rc2\=%~dp0LANG\!")2>nul

xcopy /q/s/y/r/h "%~dp0SP1rc2\*ru-ru*" "%~dp0LANG\"
xcopy /q/s/y/r/h "%~dp0SP1rc2\*en-us*" "%~dp0LANG\"

dorosa · Отправлено: **13:37, 19-01-2011** | #5

Цитата amel27:

добавить обработку папок: »

Получается тоже самое. Папки с *ru-ru* и *en-us* не копируются.

SendMessage · Отправлено: **15:44, 19-01-2011** | #6

А так?

Код:

SETLOCAL EnableDelayedExpansion
for /f %%i in ('dir /b/s/ad "%~dp0SP1rc2\" ^| findstr /i ".*ru-ru.* .*en-us.*"') do (
   set "d=%%i"
   xcopy /q/s/y/r/h "!d!" "!d:%~dp0SP1rc2\=%~dp0LANG\!\"
   )
xcopy /q/s/y/r/h "%~dp0SP1rc2\*ru-ru*" "%~dp0LANG\"
xcopy /q/s/y/r/h "%~dp0SP1rc2\*en-us*" "%~dp0LANG\"

dorosa · Отправлено: **18:02, 19-01-2011** | #7

Цитата SendMessage:

А так? »

Все отлично!
Спасибо!!!

Smith_Wesson · Отправлено: **17:16, 21-01-2011** | #8

У меня похожая ситуация, но немножко с другим условием - может кому-то, тоже пригодится...
Есть, к примеру, папка D:\my_base в которой находятся файлы вида AB_XXX.reg - ZW_XXX.reg - они всегда одного формата, но первые два символа постоянно меняются. Мне необходимо, в папке C:\ создать папку с именем каждого файла и соответственно, каждый файл копировать в папку с его(!) именем. Есть батник, вида:

Цитата:

@echo off
setlocal enableextensions enabledelayedexpansion
set MYPATH=d:\my_base\
set SOURSE=??_ХХХ.reg
for /r %MYPATH% %%i in (%SOURSE%) do md %%~Ni && echo %%~Ni >> log.log
for /r %MYPATH% %%i in (%SOURSE%) do copy %MYPATH%\??_ХХХ.reg %%~Ni

Папки создает красиво, но при этом, в каждую папку копируются ВСЕ файлы из D:\my_base, и потом приходится удалять ненужные! Как выполнять сравнение имени файла с именем папки, в которую он копируется? Чувствую, что есть хитрый способ....

SendMessage · Отправлено: **20:25, 21-01-2011** | #9

Цитата Smith_Wesson:

Папки создает красиво, но при этом, в каждую папку копируются ВСЕ файлы из D:\my_base, и потом приходится удалять ненужные! Как выполнять сравнение имени файла с именем папки, в которую он копируется? Чувствую, что есть хитрый способ.... »

Код:

@echo off

set "MYPATH=z:\my_base\"
set "SOURSE=*.reg"
for /f "tokens=*" %%i in ('dir /b/s/a-d "%MYPATH%%SOURSE%" ^| findstr /e/i "\\.._XXX\.reg"') do xcopy /r/q/i/y "%%i" "z:\%%~ni\"

Smith_Wesson · Отправлено: **14:30, 24-01-2011** | #10

SendMessage, - спасибо тебе, Добрый человек! Очень выручил!
...я правда, забыл добавить, что после этой операции, в конечных папках, и нужно паковать в архивчики, с текущей датой.
Вышел из положения такой строчкой:

Цитата:

FORFILES /P %MYPATH% /S /M *.reg /C "cmd /c icomp @file %date:~6,4%_%date:~3,2%_%date:~0,2%.z -h"

Всё работает!