[kaster]

AzazeLHAck, а зачем? сделать такое можно, но для проверки разного рода условий есть разные значения @error. Вот на них и стоит ориентироваться. Делай проверку. Обычно все так делают. Но если все же тебе нужен именно тот способ что ты описал, то

Код:

$nnn = _FileListToArray("Data","*",2)
If @error = 4 Then
      Dim $nnn[1] = 0
EndIf

[AzazeLHAck]

kaster,
Почему-то пишет Syntax error..
Общий вид таков:

Код:

Func 123()
         For     to
                $nnn = _FileListToArray("Data","*",2)
                If @error = 4 Then
                        Dim $nnn[1] = 0
                EndIf
         Next
EndFunc

В чём может быть проблема..?

[madmasles]

AzazeLHAck,
Попробуйте так:

Код:

#include <File.au3>

Func _DirListToArray($sFullPath)
    Local $aTemp, $aReturn[1] = [0]
    $aTemp = _FileListToArray($sFullPath, '*', 2)
    If Not @error Then
        $aReturn = $aTemp
    EndIf
    Return $aReturn
EndFunc   ;==>_DirListToArray

[AzazeLHAck]

madmasles,
Получилось! Спасибо!

[kaster]

Код:

         For     to

так писать нельзя. отсюда и ошибка

madmasles, в твоем коде помимо случаев когда файла/папки нет обработаются и все остальные ошибки.

[AzazeLHAck]

обработаются и все остальные ошибки. »

А там это не важно, там главное, чтобы работало

так писать нельзя. отсюда и ошибка »

Пробелы не считай, это я тут понатыкал, чтобы приблизительный внешний вид придать..

[kaster]

А там это не важно, там главное, чтобы работало »

ну тогда учти, что при
а) неправильном пути
б) неправильно введенном фильре
ты будешь получить тот же результат, что при отсутствии файлов/папок в указанной папке

Пробелы не считай »

я говорил не про пробелы, они роли не играют. дело в структуре цикла, нельзя не указывать начальный и конечные индексы.

[madmasles]

kaster,
Вопрос изначально был

если папок в папке Data нет, то чтобы он не просто возвращал 0, а вносил его так: $nnn[0] = 0 »

Если надо обработать ошибки, то можно поменять на

Код:

#include <File.au3>
#include <Array.au3>

Global $aDir, $sText = 'Все OK!'

$sPath = @DesktopDir & '\MyFolder'

$aDir = _DirListToArray($sPath)
Switch @error
    Case 1
        $sText = 'Нет такой папки.'
    Case 2
        $sText = 'Это не папка.'
    Case 4
        $sText = 'Нет папок.'
EndSwitch
_ArrayDisplay($aDir, $sText)


Func _DirListToArray($sFullPath)
    Local $aTemp, $aReturn[1] = [0]
    If Not FileExists($sFullPath) Then Return SetError(1, 0, $aReturn)
    If Not StringInStr(FileGetAttrib($sFullPath), 'D') Then Return SetError(2, 0, $aReturn)
    $aTemp = _FileListToArray($sFullPath, '*', 2)
    If Not @error Then
        $aReturn = $aTemp
    EndIf
    Return SetError(@error, 0, $aReturn)
EndFunc   ;==>_DirListToArray

[kaster]

если папок в папке Data нет »

за него отвечает @error = 4. зачем остальные коды ошибок?