[решено] Режимы MessageLoop и OnEvent Mode

Creat0R · Конфигурация компьютера

Немного по теме: http://autoit-script.ru/index.php/topic,459.0.html

Цитата saavaage:

как действует в этом случае MessageLoop? »

Смотря что в нём происходит, если дополнительный цикл, тогда будет также останавливать.

Цитата saavaage:

Значит ли это, что машина со старым процессором может отработать скрипт неполностью »

Не сталкивался с подобным, не должно оно влиять. В любом случае GUIGetMsg содержит в себе паузу примерно в 10 мс, поэтому добавлять паузы в цикл больше не нужно.

Цитата saavaage:

В справке указано, что MessageLoop, не смотря на цикл, не грузит процессор »

Ну если в цикле нет паузы (Sleep) и не опрашивается с GUIGetMsg, то нагрузка будет).

Цитата saavaage:

Логично предположить, что он также не грузит процессор. Я прав? »

Логично, событие вызывается при неком действий, а цикл проверяет всегда (если скрипт не блокируется функцией).

Цитата saavaage:

Какой из них менее ресурсоемкий и более надежный? »

Вместе не получится, нужно разделить два этих критерия

MessageLoop надёжнее в плане удобства и доступности, но в то же время он может быть ресурсоёмким. А режим OnEvent он более сложный для работы с многими окнами и элементами, однако ресурсов в большинстве случаев потребляет меньше... хотя это всё поддаётся сравнению, прочитайте тему по ссылке что я привёл в начале, там это расписано.

Цитата saavaage:

использовать вариант MessageLoop - для общих кнопок, а вариант OnEvent Mode - для кнопок на конкретной вкладке »

Это как?

совмещать режимы для одного GUI не получится.

Цитата saavaage:

лучше использовать только вариант MessageLoop »

Если нет дочерних окон, то да.

Цитата saavaage:

лучше использовать только вариант OnEvent Mode »

Если есть дочерние окна которые создаются по запросу (по кнопке, в функций к примеру).

Цитата saavaage:

все равно »

Можно и так

saavaage · Конфигурация компьютера

Creat0R, спасибо за развернутый ответ. Есть еще один вопрос по форме с вкладками: как сделать так, чтобы скрипты, находящиеся в привязке к определенной вкладке Tab, отрабатывали только тогда, когда я перехожу на эту вкладку (делаю ее активной), а не при загрузке всей формы. Просто, при большом количестве вкладок и скриптов, вся прога грузится довольно долго, пока не обработаются все скрипты вкладок.
Спасибо

Creat0R · Конфигурация компьютера

Цитата saavaage:

Есть еще один вопрос по форме с вкладками »

Этот вопрос заслуживает отдельной темы (где не помешало бы выложить пример этой самой формы).

saavaage · Конфигурация компьютера

Creat0R, так и сделаю

Creat0R · Конфигурация компьютера

Цитата saavaage:

так и сделаю »

Эта тема решена?

saavaage · Конфигурация компьютера

Creat0R, так точно, сэр :-). Закрываю.

saavaage · Конфигурация компьютера

Creat0R, извините, но обнаружил на русском форуме Autoit Ваше высказывание на тему MessageLoop vs OnEvent Mode:
пост http://autoit-script.ru/index.php/topic,459.0.html
цитата: "Это всё зависит от поставленной задачи. Иногда лучше использовать MessageLoop (например если некие элементы вызывают дочернее окно которое также требует обработку событий), а иногда лучше OnEvent. "

Оно противоречит Вашему ответу в текущем посте:

Цитата Creat0R:

лучше использовать только вариант MessageLoop »
Если нет дочерних окон, то да. »

Дело в том, что я планирую делать подчиненное окно с настройками утилиты, где будут:
выпадающий список (combo), внесение твика в реестр (прописывание в автозагрузке), кнопка сохранения и закрытия
и для меня очень важно сразу определиться какой режим лучше использовать, чтобы потом не переделывать скрипт.

Спасибо

Creat0R · Конфигурация компьютера

Цитата saavaage:

Оно противоречит Вашему ответу в этом посте »

И в чём же противоречие? и там и там я пишу про то что в неких ситуациях лучше использовать «MessageLoop».

Цитата saavaage:

я планирую делать подчиненное окно с настройками утилиты »

Вариант с MessageLoop:

Код:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region Main GUI
$hMain_GUI = GUICreate("My Program", 500, 300)
$nMain_Exit_Button = GUICtrlCreateButton("Exit", 20, 270, 60, 20)
$nMain_Settings_Button = GUICtrlCreateButton("Settings", 90, 270, 60, 20)
GUISetState(@SW_SHOW, $hMain_GUI)
#EndRegion Main GUI

#Region Settings GUI
$hSettings_GUI = GUICreate("Settings", 400, 250, -1, -1, -1, -1, $hMain_GUI)
$nStngs_Close_Button = GUICtrlCreateButton("Close", 20, 220, 60, 20)
$nStngs_Save_Button = GUICtrlCreateButton("Save", 90, 220, 60, 20)
#EndRegion Settings GUI

While 1
    $nMsg = GUIGetMsg(1)

    Switch $nMsg[0]
        Case $GUI_EVENT_CLOSE, $nStngs_Close_Button, $nMain_Exit_Button
            If $nMsg[1] = $hSettings_GUI Then
                GUISetState(@SW_ENABLE, $hMain_GUI)
                GUISetState(@SW_HIDE, $hSettings_GUI)
            Else
                Exit
            EndIf
        Case $nMain_Settings_Button
            GUISetState(@SW_DISABLE, $hMain_GUI)
            GUISetState(@SW_SHOW, $hSettings_GUI)
        Case $nStngs_Save_Button
            MsgBox(64, 'Title', 'Settings saved!', 0, $hSettings_GUI)
    EndSwitch
WEnd

Вариант с OnEvent:

Код:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

#Region Main GUI
$hMain_GUI = GUICreate("My Program", 500, 300)
$nMain_Exit_Button = GUICtrlCreateButton("Exit", 20, 270, 60, 20)
$nMain_Settings_Button = GUICtrlCreateButton("Settings", 90, 270, 60, 20)

GUICtrlSetOnEvent($nMain_Exit_Button, "_MainGUI_Events")
GUICtrlSetOnEvent($nMain_Settings_Button, "_MainGUI_Events")
GUISetOnEvent($GUI_EVENT_CLOSE, "_MainGUI_Events", $hMain_GUI)

GUISetState(@SW_SHOW, $hMain_GUI)
#EndRegion Main GUI

#Region Settings GUI
$hSettings_GUI = GUICreate("Settings", 400, 250, -1, -1, -1, -1, $hMain_GUI)
$nStngs_Close_Button = GUICtrlCreateButton("Close", 20, 220, 60, 20)
$nStngs_Save_Button = GUICtrlCreateButton("Save", 90, 220, 60, 20)

GUICtrlSetOnEvent($nStngs_Close_Button, "_SettingsGUI_Events")
GUICtrlSetOnEvent($nStngs_Save_Button, "_SettingsGUI_Events")
GUISetOnEvent($GUI_EVENT_CLOSE, "_SettingsGUI_Events", $hSettings_GUI)
#EndRegion Settings GUI

While 1
    Sleep(100)
WEnd

Func _MainGUI_Events()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE, $nMain_Exit_Button
            Exit
        Case $nMain_Settings_Button
            GUISetState(@SW_DISABLE, $hMain_GUI)
            GUISetState(@SW_SHOW, $hSettings_GUI)
    EndSwitch
EndFunc

Func _SettingsGUI_Events()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE, $nStngs_Close_Button
            GUISetState(@SW_ENABLE, $hMain_GUI)
            GUISetState(@SW_HIDE, $hSettings_GUI)
        Case $nStngs_Save_Button
            MsgBox(64, 'Title', 'Settings saved!', 0, $hSettings_GUI)
    EndSwitch
EndFunc

Хотя я лично предпочитаю в таком случае создавать GUI в функций, и временно изменить с OnEvent на MessageLoop, так мне кажется удобнее, тем более что так меньше ресурсов потребляет:

Подробнее

Выбирай

saavaage · Конфигурация компьютера

Creat0R, большое спасибо (особенно за 3 вариант)

PS противоречие было в том, что в первой цитате Вы рекомендовали использовать MessageLoop с дочерними окнами, а во-второй, наоборот, если нет дочерних окон.

Не заглянете в тему http://forum.oszone.net/thread-182740.html ? Там у нас небольшая проблема возникла с ограничением вывода инфо в ListViewItem