[решено] Скрипт для окна Missing File в Adobe Framemaker

Creat0R · Конфигурация компьютера

Вобщем вот что получилось:

Код:

Opt("WinWaitDelay", 0)

$sTitle = "[CLASS:#32770;TITLE:Missing File]"
$sText = "FolderView"

While WinExists($sTitle, $sText)
    ControlClick($sTitle, $sText, "[CLASS:Button; INSTANCE:6; TEXT:&Skip This File]")
    ControlClick($sTitle, $sText, "[CLASS:Button; INSTANCE:2; TEXT:&Continue]")

    Sleep(10) ;Это можно убрать если требуется мгновенная обработка, однако это может повлечь за собой нагрузку на ЦП
WEnd

Но насколько я пониманию, после первого нажатия на «Continue» окно исчезнет, и тут возникает вопрос - как определить что окно больше не появится, или сколько ожидать отсутствие окна прежде чем выйти из скрипта?

Vadikan · Конфигурация компьютера

Спасибо! Пока не работает

Цитата Creat0R:

Но насколько я пониманию, после первого нажатия на «Continue» окно исчезнет »

Сорри, я не совсем точно сформулировал проблему. Последовательность такая получается при ручном вводе.

1. Выбор "Skip This File"
2. Нажатие "Continue" пропускает потерянный файл.
3. Окно закрывается, но Framemaker тут же ищет следующий "потерянный файл" и выводит очередное точно такое же окно, просто вверху, где "Looking for" другое имя файла.

После чего все повторяется до тех пор, пока все потерянные файлы не пропущены.

К сожалению, нажимать Ignore All Missing files нельзя.

Creat0R · Конфигурация компьютера

Vadikan, Но опять же, остаётся вопрос определения - как скрипт будт знать что окон болше не будет появляться? или может просто нужно установить промежуток времени, по истечению которого будет считаться что окно больше не появится?

P.S
У тебя есть возможность проверять сам скрипт, или обязательно нужно компилировать? Просто было бы проще проверять au3 скрипт пока мы найдём рабочий вариант

Vadikan · Конфигурация компьютера

Цитата Creat0R:

или может просто нужно установить промежуток времени, по истечению которого будет считаться что окно больше не появится? »

5 секунд будет достаточно.

Цитата Creat0R:

У тебя есть возможность проверять сам скрипт, или обязательно нужно компилировать? »

Теперь есть.

Creat0R · Конфигурация компьютера

Цитата Vadikan:

5 секунд будет достаточно »

Вариант №2:

Код:

Opt("WinWaitDelay", 0)

$sTitle = "[CLASS:#32770;TITLE:Missing File]"
$sText = ""

While 1
    _WinWaitVisible($sTitle, $sText, 5)
    If Not _WinVisible($sTitle, $sText) Then Exit

    ControlCommand($sTitle, $sText, "Button6", "Check")
    Sleep(10)
    ControlClick($sTitle, $sText, "Button2")
WEnd

Func _WinWaitVisible($sTitle, $sText, $iTime=0)
    Local $iTimer = -1
    If $iTime > 0 Then $iTimer = TimerInit()

    While Not _WinVisible($sTitle, $sText)
        Sleep(10)
        If $iTime > 0 And (TimerDiff($iTimer) / 1000) >= $iTime Then ExitLoop
    WEnd

    Return _WinVisible($sTitle, $sText)
EndFunc

Func _WinVisible($sTitle, $sText="")
    Return Number(BitAND(WinGetState($sTitle, $sText), 2) = 2)
EndFunc

Vadikan · Конфигурация компьютера

Creat0R, супер, то что доктор прописал! Спасибо!