[Frost_Imp]

мммм, вставить в эксель и сделать "текст по столбцам"
Руками или средствами AutoIt - дело вкуса)

[Creat0R]

необходима функция обрезающая строку до указанного символа ":" с левой стороны затем с правой »

Причём у каждой строки, вот пример с использованием StringRegExp:

Код:

$sInFile = @ScriptDir & "\File.txt"
$sOutFile_IPs = @ScriptDir & "\IPs.txt"
$sOutFile_Ports = @ScriptDir & "\Ports.txt"

$sReadFile = FileRead($sInFile)
$aRet = StringRegExp($sReadFile, '((?:[0-9]{1,3}\.?){4}):([0-9]{1,4})', 3)

$sOutFile_IPs_Content = ""
$sOutFile_Ports_Content = ""

For $i = 0 To UBound($aRet)-1
    If Mod($i, 2) = 0 Then ;Чётное число (или 0), пишем IP'шки
        $sOutFile_IPs_Content &= $aRet[$i] & @CRLF
    Else ;Иначе пишем порты
        $sOutFile_Ports_Content &= $aRet[$i] & @CRLF
    EndIf
Next

$hFile = FileOpen($sOutFile_IPs, 2)
FileWrite($hFile, $sOutFile_IPs_Content)
FileClose($hFile)

$hFile = FileOpen($sOutFile_Ports, 2)
FileWrite($hFile, $sOutFile_Ports_Content)
FileClose($hFile)

вставить в эксель и сделать "текст по столбцам" »

Такие советы лучше не озвучивать, они бессмыслены.

[Stomper]

Думаю, из файла сами считаете... так же как и положите. Или посмотрите примеры. Берем адрес и порт из строки таким образом:

Код:

  $s="61.172.246.180:80"
  $pos=StringInStr($s,":")
  MsgBox(0,"",StringLeft($s,$pos-1));
  MsgBox(0,"",StringMid($s,$pos+1,StringLen($s)-$pos))

[kaster]

ну или

Код:

$aLine = StringSplit($sLine, ':')
$sIP = $aLine[1]
$sPort = $aLine[2]

[Stomper]

kaster, оу Признаю, у вас красивее